2nd Tutorial on PSpice

Simple Dependent Sources

We now extend our circuit parts list by adding the most basic dependent sources.   The four dependent sources we now encounter are simple multiples of the controlling voltage or current.  It is possible to model dependent sources that are complex nonlinear functions of several controlling voltages and/or currents.  However, we will now concentrate on the basic linear dependent sources.

Voltage Controlled Dependent Voltage Source

voltage-controlled dependent voltage source with controlling branch

In the above figure, we find the dependent source whose positive terminal is designated as "n+" and whose negative terminal is designated as "n-."  The controlling voltage is a branch voltage at some other circuit location.  In this case, the positive terminal of the controlling branch is designated as "nc+" while the negative terminal is designated as "nc-"   The "gain" of the dependent voltage source is a, a dimensionless quantity.  For example, if vx happened to be 16.0 volts while a = 4, then node "n+" would be at 64.0 volts higher potential than node "n-."

The first letter of the part name for the voltage-controlled dependent voltage source is "E."  This is the letter that must appear in column 1 of the *.CIR file describing the circuit.  Some examples of the voltage-controlled dependent voltage source PSpice entries follow.

*Name   n+  n-   nc+  nc-   gain
Ebar    17   8   42   18    24.0; gain is 24
efix     3   1   11    0    20.0
efix     3   1    0   11   -20.0; same as above
efix     1   3   11    0   -20.0; same as above
efix     1   3    0   11    20.0; same as above
Ellen   12   0   20   41    16.0

Voltage Controlled Dependent Current Source

voltage-controlled dependent current source with controlling branch

In the above voltage-controlled dependent current source a current equal to g times vx flows from node "n+" through the source and out node "n-."  γ is called the transconductance and has the dimensions of siemens (inverse ohms).  For example, if the controlling branch voltage, vx , equals 6.0 volts and the transconductance, γ, is 0.25 siemens, the current produced by the dependent source is 1.5 amps.

The first letter of the part name for the voltage-controlled dependent current source is "G."  Some examples of how this part is coded into the *.CIR file are shown below.

*Name n+   n-   NC+    NC   transconductance
Glab  23   17     8     3    2.5
G1    12    9     1     0    4E-2
Grad  19   40     6    99    0.65
Grad  19   40    99     6   -0.65 ; same as above
Grad  40   19    99     6    0.65 ; etc.

Current Controlled Dependent Voltage Source

current-controlled dependent voltage source with controlling branch

The current-controlled dependent voltage source as shown above, produces a voltage proportional to the current, ix, in a different branch of the network.  The transresistance, ρ, in ohms is multiplied by ix in amps to produce the dependent source voltage in volts.   Unlike the two previous examples, we cannot simply designate the controlling branch by its nodes.  Since there could be multiple branches carrying very different currents between any pair of nodes, we must explicitly identify the branch of the controlling current.  Eventually, we will be able to do this with any type of element.  However, the only reliable method of doing this at present is to use an independent voltage source as an ammeter to report the current of the controlling branch to the dependent source.  Usually, this means you must insert a zero-valued independent voltage source in series with the branch containing the controlling current so that the controlling current enters the positive terminal of the independent voltage source.  However, if there happens to be an independent voltage source that monitors the controlling current you can use it.  If necessary, use a minus sign to get the right polarity.

The first letter of the part name for the current-controlled dependent voltage source is "H."  Some examples follow for this device.

*Name n+  n- Vmonitor  transresistance
Hvx  20  12  Vhx       50.0
Vhx  80  76  DC        0V ; controls Hvx

Hab  10   0  V20       75.0
V20  15   5  DC        0V ; controls Hab

HAL  20  99  Vuse      10.0
Vuse  3   5  DC       20V ; actual voltage source

Current Controlled Dependent Current Source

current-controlled dependent current source with controlling branch

The current-controlled dependent current source produces a current proportional to the controlling current, ix, flowing in a different branch.   The current gain, β, is dimensionless.  Designating the control scheme is similar to setting up the current-controlled dependent voltage source previously discussed.  We must use a voltage source connected in series with the controlling element so that the controlling current enters the positive terminal of the independent voltage source used as an ammeter.  If no voltage source is needed for its voltage, we use a zero-valued voltage source as shown in the figure.

The first letter in the part name for this dependent source is "F."  The syntax for entering this part in *.CIR files is shown in several examples below.

*Name  n-   n+   Vmonitor    Gain
Ftrn   81   19   Vctl         50.0
Vclt   23   12   DC           0V ; controls Ftrn

Fcur   63   48   Vx           20.0
Vx     33   71   DC           0V ; controls Fcur

F3      2    0   V1           15.0
V1      3    1   DC           0V ; controls F3

Using PSpice to find Thévenin Equivalent Circuit

In addition to performing general purpose circuit analysis, PSpice can be used to determine the Thévenin resistance and open circuit voltage of a circuit.  This can be of great advantage if the circuit is complex, with several dependent sources, or if the circuit cannot be reduced by successive source transformations.  The PSpice "dot command" that makes this easy, is ".TF," where "TF" indicates "transfer function."  The transfer function is intended to find the ratio between a source voltage or current, and a resulting voltage difference or branch current.   This is useful in characterizing circuits.  In addition to reporting the calculated transfer function ratio and input resistance at the source, PSpice reports the output resistance at the terminal pair of interest.  The voltage across the terminal pair of interest is the Thévenin voltage and the output resistance is the Thévenin resistance.  At this point we will ignore the transfer function ratio and the input resistance at the source.  In fact, we do not care which source is chosen as long as we only want the Thévenin equivalent circuit parameters.  An example of the syntax for the .TF command is shown below.

*command output_variable input_source
.TF      V(4)             Vs

The above command will report the ratio between source Vs and node voltage V(4).   If we wanted the Thévenin circuit from nodes 4 to 0, the output resistance reported would be our Thévenin resistance, and the voltage V(4) would be the Thévenin (open circuit) voltage.  The input source can be a voltage or a current source, and the output variable can be a node voltage, branch voltage or a device current.  Now we examine a specific example.

Example Circuit for Thevenin Equivalent Circuit

In this example, we want the Thévenin equivalent circuit from nodes 1 to 0.  The 1 Megohm resistor is placed in the circuit because PSpice requires at least two connections to each node.  This resistor is large enough that it will not have an effect on the calculations.  Note the use of voltage source Vc which has the purpose of monitoring the control current, ix, used for the current-controlled dependent current source, Fx.  The input lines in the *.CIR file are shown below.

Thevenin Example No. 1
Vs   2   5   DC     100V
Vc   2   3   DC       0V; controls Fx
Fx   6   7   Vc      4.0; gain = 4
*   n+  n-  NC+ NC gain
Ex   2   1   5  4   3.0; gain = 3 
R1   3   4   5.0
R2   4   7   5.0
R3   5   4   4.0
R4   7   0   4.8
R5   5   6   1.0
R10  1   0   1MEG; satisfies PSpice
*   out_var  input_source
.TF  V(1,0)  Vs

Portions of the output file produced by this case will now be listed.

Thevenin Example No. 1
Vs 2 5 DC 100V
Vc 2 3 DC 0V; controls Fx
Fx 6 7 Vc 4.0; gain = 4.0
Ex 2 1 5 4 3.0; gain = 3.0
R1 3 4 5.0
R2 4 7 5.0
R3 5 4 4.0
R4 7 0 4.8
R5 5 6 1.0
Rab 1 0 1MEG
.TF V(1,0) Vs

Thevenin Example No. 1
( 1)  180.0000 ( 2) -60.0010  ( 3) -60.0010  ( 4) -80.0010
( 5) -160.0000 ( 6) -176.0000 ( 7)-864.0E-06
Vs -4.000E+00
Vc  4.000E+00
V(1,0)/Vs = 1.800E+00 <== Transfer function
OUTPUT RESISTANCE AT V(1,0) = 5.000E+00 <== Thévenin resistance

We conclude that the Thévenin resistance is 5 ohms and the open circuit voltage is 180 volts.  Use of the .TF function allows us to get the answers in a single job.   The alternative to using the .TF function would be to run one case with a large resistor across the terminal pair of interest (if necessary) to get the open circuit voltage; and then run a second case with a zero-valued voltage source across the terminal pair to get the short circuit current.  Then divide the short circuit current into the open circuit voltage to get the Thévenin resistance.  We prefer the ".TF" method for obtaining Thévenin equivalent circuits.

Back to Main Page